Opcodes

cabbageCreate

This opcode will create a new widget based on a JSON object. Note that widgets generated in this way cannot be registered as parameters. This means they cannot be automated by the host. Note this opcode only runs at i-time.

Syntax

cabbageCreate:i(SJson)

Initialization

SJson – a well-formed JSON string. This will typically look like a JSON object from the Cabbage section JSON array.

Example:

1
<Cabbage>
2
{
3
    "pluginId"      : "def1",
4
    "enableDevTools": true,
5
    "channelConfig": [
6
        { "name": "Stereo",    "ins": "2",   "outs": "2" }
7
    ],
8
    "widgets"       : [
9
        { "type": "form", "caption": "Template Effect", "size": {"width": 580, "height": 370} },
10
        {
11
            "type"    : "image",
12
            "id"      : "scrubber",
13
            "bounds"  : {"left": 9, "top": 9, "width": 32, "height": 278},
14
            "channels": [
15
                { "id": "image130", "range": {"increment": 0.001} }
16
            ],
17
            "style"   : {"backgroundColor": "#0295cffd"},
18
            "zIndex"  : -1
19
        },
20
        {
21
            "type"    : "horizontalSlider",
22
            "id"      : "horizontalSlider133",
23
            "bounds"  : {"top": 297, "width": 233, "height": 30},
24
            "channels": [
25
                { "id": "bpmSlider", "range": {"defaultValue": 60, "increment": 1, "max": 320} }
26
            ],
27
            "label"   : {"text": "BPM"}
28
        },
29
        {
30
            "type"    : "button",
31
            "id"      : "randomBtn",
32
            "bounds"  : {"left": 254, "top": 297, "width": 100},
33
            "channels": [ {"id": "shuffle", "range": {}} ],
34
            "label"   : { "text": {"on": "Shuffle", "off": "Shuffle"} }
35
        }
36
    ]
37
}
38

39
</Cabbage>
40
<CsoundSynthesizer>
41
<CsOptions>
42
-n -d
43
</CsOptions>
44
<CsInstruments>
45
ksmps = 32
46
nchnls = 2
47
0dbfs = 1
48

49
instr 1
50

51
    x:i, y:i init 0
52
    widgetCount:i init 0
53
    while y < 8 do
54
        while x < 16 do
55
            SWidget = sprintf({{
56
            {
57
            "type": "checkBox",
58
            "bounds":{"left":%d, "top":%d, "width":30, "height":30},
59
            "channels": [{"id": "check%d"}],
60
            "style": {
61
            "on": {"backgroundColor": "#ffa71e"},
62
            "off": {"backgroundColor": "#d5d5d5ff"}
63
            },
64
            "automatable":false
65
            }
66
            }}, 10+x*35, 10+y*35, widgetCount)
67
            cabbageCreate(SWidget)
68
            widgetCount += 1
69
            x += 1
70
        od
71
        x = 0
72
        y += 1
73
    od
74

75
    notes:i[] = [48, 50, 52, 53, 55, 57, 59, 60, 62]
76
    column:k init 0
77
    scrubberPos:k init 0
78
    numRows:i = 8
79
    numCols:i = 16
80
    bpm:k = cabbageGetValue("bpmSlider")
81

82
    if metro:k(bpm/60)==1 then
83
        row:k = 0
84
        while row<numRows do
85
            checkNum:k = column + row*numCols
86
            val:k = cabbageGetValue(sprintfk("check%d", checkNum))
87
            if val == 1 then
88
                event("i", "Synth", 0, 1, chnget:k("octave")+notes[7-row], .3)
89
            endif
90
            row = row+1
91
        od
92
        cabbageSet(1, "scrubber", "bounds.left", (column*35+9))
93
        column = (column+1) % numCols
94
    endif
95

96
    shuffle:CabbageNumTrig = cabbageGetValue("shuffle")
97
    if shuffle.trig==1 then
98
        event("i", "SHUFFLE", 0, .5)
99
    endif
100
endin
101

102
instr Synth
103
    print p4
104
    aEnv = expon(p5, p3, 0.01)
105
    aOut = oscil(aEnv, cpsmidinn(p4))
106
    outs(aOut, aOut)
107
endin
108

109
instr SHUFFLE
110
    prints "Shuffling hits"
111
    index:i init 0
112

113
    while index < 128 do
114
        randVal:i = rnd(100) > 80 ? 1 : 0
115
        SChannel = sprintfk("check%d", index)
116
        cabbageSetValue:i(SChannel, randVal)
117
        index += 1
118
    od
119
endin
120
</CsInstruments>
121
<CsScore>
122
f1 0 4096 10 1 .5 .25 .17
123
i1 0 z
124
</CsScore>
125
</CsoundSynthesizer>

Download cabbageCreate.csd

Extended example

A larger step-sequencer built on the same cabbageCreate technique:

1
<Cabbage>
2
{
3
    "pluginId": "def1",
4
    "widgets": [
5
        {
6
            "type"    : "form",
7
            "id"      : "MainForm",
8
            "caption" : "Template Effect",
9
            "size"    : {"width": 640, "height": 380},
10
            "channels": [ {"id": "formChannel"} ]
11
        },
12
        {
13
            "//"      : "----------- Scrubber to indicate the current column being played ----------",
14
            "type"    : "image",
15
            "id"      : "scrubber",
16
            "bounds"  : {"left": 9, "top": 9, "width": 32, "height": 278},
17
            "channels": [
18
                { "id": "image130", "range": {"increment": 0.001} }
19
            ],
20
            "style"   : {"backgroundColor": "#0295cf28"},
21
            "zIndex"  : -1
22
        },
23
        {
24
            "//"      : "----------- A button to shuffle the grid pattern randomly ----------",
25
            "type"    : "button",
26
            "id"      : "randomBtn",
27
            "bounds"  : {"left": 9, "top": 334, "width": 100, "height": 30},
28
            "channels": [ {"id": "shuffle", "range": {}} ],
29
            "label"   : { "text": {"on": "Shuffle", "off": "Shuffle"} },
30
            "style"   : {
31
                "on"        : {"backgroundColor": "#ffa71e14", "textColor": "#ffffff"},
32
                "off"       : {"backgroundColor": "#ffa71e14", "textColor": "#ffffff"},
33
                "hover"     : {"backgroundColor": "#fbfbfb6d"},
34
                "fontFamily": "Arial",
35
                "fontSize"  : 10,
36
                "textAlign" : "centre"
37
            }
38
        },
39
        {
40
            "//"      : "---------- A button to start and stop the sequencer ----------",
41
            "type"    : "button",
42
            "id"      : "statStopBtn",
43
            "bounds"  : {"left": 9, "top": 298, "width": 100},
44
            "channels": [ {"id": "startStop", "range": {}} ],
45
            "label"   : { "text": {"on": "Stop", "off": "Start"} },
46
            "style"   : {
47
                "on"        : {"backgroundColor": "#ffa71e", "textColor": "#ffffff"},
48
                "off"       : {"backgroundColor": "#ffa71e14", "textColor": "#ffffff"},
49
                "hover"     : {"backgroundColor": "#fbfbfb2e"},
50
                "fontFamily": "Arial",
51
                "fontSize"  : 10,
52
                "textAlign" : "centre"
53
            }
54
        },
55
        {
56
            "//"      : "======== Number sliders to set the MIDI note ==========",
57
            "type"    : "numberSlider",
58
            "id"      : "numberSlider1",
59
            "bounds"  : {"left": 569, "width": 52, "height": 30},
60
            "channels": [
61
                { "id": "rowNote1", "range": {"defaultValue": 60, "increment": 1, "max": 72, "min": 48} }
62
            ],
63
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
64
        },
65
        {
66
            "type"    : "numberSlider",
67
            "id"      : "numberSlider2",
68
            "bounds"  : {"left": 569, "top": 45, "width": 52, "height": 30},
69
            "channels": [
70
                { "id": "rowNote2", "range": {"defaultValue": 59, "increment": 1, "max": 72, "min": 36} }
71
            ],
72
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
73
        },
74
        {
75
            "type"    : "numberSlider",
76
            "id"      : "numberSlider3",
77
            "bounds"  : {"left": 569, "top": 80, "width": 52, "height": 30},
78
            "channels": [
79
                { "id": "rowNote3", "range": {"defaultValue": 57, "increment": 1, "max": 72, "min": 36} }
80
            ],
81
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
82
        },
83
        {
84
            "type"    : "numberSlider",
85
            "id"      : "numberSlider4",
86
            "bounds"  : {"left": 569, "top": 115, "width": 52, "height": 30},
87
            "channels": [
88
                { "id": "rowNote4", "range": {"defaultValue": 55, "increment": 1, "max": 72, "min": 36} }
89
            ],
90
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
91
        },
92
        {
93
            "type"    : "numberSlider",
94
            "id"      : "numberSlider5",
95
            "bounds"  : {"left": 569, "top": 150, "width": 52, "height": 30},
96
            "channels": [
97
                { "id": "rowNote5", "range": {"defaultValue": 53, "increment": 1, "max": 72, "min": 36} }
98
            ],
99
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
100
        },
101
        {
102
            "type"    : "numberSlider",
103
            "id"      : "numberSlider6",
104
            "bounds"  : {"left": 569, "top": 185, "width": 52, "height": 30},
105
            "channels": [
106
                { "id": "rowNote6", "range": {"defaultValue": 52, "increment": 1, "max": 72, "min": 36} }
107
            ],
108
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
109
        },
110
        {
111
            "type"    : "numberSlider",
112
            "id"      : "numberSlider7",
113
            "bounds"  : {"left": 569, "top": 220, "width": 52, "height": 30},
114
            "channels": [
115
                { "id": "rowNote7", "range": {"defaultValue": 50, "increment": 1, "max": 72, "min": 36} }
116
            ],
117
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
118
        },
119
        {
120
            "type"    : "numberSlider",
121
            "id"      : "numberSlider8",
122
            "bounds"  : {"left": 569, "top": 255, "width": 52, "height": 30},
123
            "channels": [
124
                { "id": "rowNote8", "range": {"defaultValue": 48, "increment": 1, "max": 72, "min": 36} }
125
            ],
126
            "style"   : { "label": {"fontSize": 12}, "valueText": {"fontColor": "#e3e3e3"} }
127
        },
128
        {
129
            "//"       : "----------- A slider to control BPM ----------",
130
            "type"     : "rotarySlider",
131
            "id"       : "bpmSlider",
132
            "bounds"   : {"left": 122, "top": 289, "width": 52},
133
            "channels" : [
134
                { "id": "bpmSlider", "range": {"defaultValue": 240, "increment": 1, "max": 360, "min": 1} }
135
            ],
136
            "label"    : {"text": "BPM", "align": "top", "offsetY": 3},
137
            "valueText": {"visible": true, "offsetY": -5},
138
            "style"    : {
139
                "thumb"    : {"backgroundColor": "#FF5252", "borderColor": "#2a2a2a", "borderWidth": 2},
140
                "track"    : {"width": 4, "fillColor": "#ededed"},
141
                "label"    : {"fontSize": 12},
142
                "valueText": {"fontSize": 12, "fontColor": "#e3e3e3"}
143
            }
144
        },
145
        {
146
            "//"       : "----------- A slider to control duration ----------",
147
            "type"     : "rotarySlider",
148
            "id"       : "durationSlider",
149
            "bounds"   : {"left": 258.5, "top": 289, "width": 54},
150
            "channels" : [
151
                { "id": "durationSlider", "range": {"defaultValue": 1, "increment": 0.1, "max": 10, "min": 0.1} }
152
            ],
153
            "label"    : {"text": "Note Dur.", "align": "top", "offsetY": 3},
154
            "valueText": {"visible": true, "offsetY": -5},
155
            "style"    : {
156
                "thumb"    : {"backgroundColor": "#FFB142", "borderColor": "#2a2a2a", "borderWidth": 2},
157
                "track"    : {"width": 4, "fillColor": "#ededed"},
158
                "label"    : {"fontSize": 12},
159
                "valueText": {"fontSize": 12, "fontColor": "#e3e3e3"}
160
            }
161
        },
162
        {
163
            "//"       : "----------- A slider to control probability ----------",
164
            "type"     : "rotarySlider",
165
            "id"       : "probabilitySlider",
166
            "bounds"   : {"left": 190.25, "top": 289, "width": 52},
167
            "channels" : [
168
                { "id": "probability", "range": {"defaultValue": 10, "increment": 1, "max": 100, "min": 1} }
169
            ],
170
            "label"    : {"text": "Prob.", "align": "top", "offsetY": 3},
171
            "valueText": {"offsetY": -5, "visible": true},
172
            "style"    : {
173
                "thumb"    : {"backgroundColor": "#2ED573", "borderColor": "#2a2a2a", "borderWidth": 2},
174
                "track"    : {"width": 4, "fillColor": "#ededed"},
175
                "label"    : {"fontSize": 12},
176
                "valueText": {"fontSize": 12, "fontColor": "#e3e3e3"}
177
            }
178
        },
179
        {
180
            "//"       : "----------- A slider to control delay ----------",
181
            "type"     : "rotarySlider",
182
            "id"       : "delaySlider",
183
            "bounds"   : {"left": 328.75, "top": 289, "width": 52},
184
            "channels" : [
185
                { "id": "delayTime", "range": {"defaultValue": 1, "increment": 0.01, "max": 4, "min": 0} }
186
            ],
187
            "label"    : {"text": "Del. Time", "align": "top", "offsetY": 3},
188
            "valueText": {"offsetY": -5, "visible": true},
189
            "style"    : {
190
                "thumb"    : {"backgroundColor": "#A55EEA", "borderColor": "#2a2a2a", "borderWidth": 2},
191
                "track"    : {"width": 4, "fillColor": "#ededed"},
192
                "label"    : {"fontSize": 12},
193
                "valueText": {"fontSize": 12, "fontColor": "#e3e3e3"}
194
            }
195
        },
196
        {
197
            "//"       : "----------- A slider to control delay feedback ----------",
198
            "type"     : "rotarySlider",
199
            "id"       : "feedbackSlider",
200
            "bounds"   : {"left": 397, "top": 289, "width": 52},
201
            "channels" : [
202
                { "id": "delayFeedback", "range": {"defaultValue": 0, "increment": 0.01, "max": 0.999, "min": 0} }
203
            ],
204
            "label"    : {"text": "Del. Fdbk.", "align": "top", "offsetY": 3},
205
            "valueText": {"offsetY": -5, "visible": true},
206
            "style"    : {
207
                "thumb"    : {"backgroundColor": "#1E90FF", "borderColor": "#2a2a2a", "borderWidth": 2},
208
                "track"    : {"width": 4, "fillColor": "#ededed"},
209
                "label"    : {"fontSize": 12},
210
                "valueText": {"fontSize": 12, "fontColor": "#e3e3e3"}
211
            }
212
        },
213
        {
214
            "//"         : "----------- A checkbox to enable auto shuffling ----------",
215
            "type"       : "checkBox",
216
            "id"         : "checkBox145",
217
            "bounds"     : {"left": 514, "top": 331, "width": 107, "height": 16},
218
            "channels"   : [ {"id": "autoShuffle", "range": {}} ],
219
            "label"      : {"text": "Auto Shuffle"},
220
            "style"      : {
221
                "off"      : {"textColor": "#dddddd"},
222
                "on"       : {"textColor": "#ffffff", "backgroundColor": "#ffa71e"},
223
                "textAlign": "right"
224
            },
225
            "persistence": {"preset": false}
226
        },
227
        {
228
            "//"         : "----------- A button to save the current state to a file ----------",
229
            "type"       : "button",
230
            "id"         : "saveStateBtn",
231
            "bounds"     : {"left": 462, "top": 297, "width": 76},
232
            "channels"   : [ {"id": "saveStateBtn", "range": {}} ],
233
            "label"      : { "text": {"on": "Save Preset", "off": "Save Preset"} },
234
            "style"      : {
235
                "on"        : {"backgroundColor": "#ffa71e", "textColor": "#ffffff"},
236
                "off"       : {"backgroundColor": "#ffa71e14", "textColor": "#ffffff"},
237
                "hover"     : {"backgroundColor": "#fbfbfb2e"},
238
                "fontFamily": "Arial",
239
                "fontSize"  : 10,
240
                "textAlign" : "centre"
241
            },
242
            "persistence": {"preset": false}
243
        },
244
        {
245
            "//"         : "----------- A combo box to load presets ----------",
246
            "type"       : "comboBox",
247
            "bounds"     : {"left": 546, "top": 296, "width": 76},
248
            "channels"   : [
249
                { "id": "presetCombo", "range": {"increment": 0.001, "max": 1}, "type": "string" }
250
            ],
251
            "style"      : {
252
                "backgroundColor": "#0295cf28",
253
                "borderColor"    : "#0295cf28",
254
                "borderRadius"   : 4,
255
                "borderWidth"    : 0
256
            },
257
            "persistence": {"preset": false},
258
            "populate"   : {"fileType": ".json", "labelWhenEmpty": "No Presets", "defaultLabel": "Load Preset"},
259
            "automatable": false
260
        }
261
    ]
262
}
263

264
</Cabbage>
265
<CsoundSynthesizer>
266
<CsOptions>
267
-n -d -m0d
268
</CsOptions>
269
<CsInstruments>
270
ksmps = 32
271
nchnls = 2
272
0dbfs = 1
273

274
numRows@global:i = 8
275
numCols@global:i = 16
276
presetDirectory@global:S = strcat(chnget:S("CSD_PATH"), "/Presets")
277
struct CabbageButton val:k, trig:k
278

279
/*------------------------------------------------*/
280
/* Create the 16x8 grid of checkboxes dynamically */
281
/*------------------------------------------------*/
282
instr CREATE_GRID
283

284
    // Populate the preset combo box with files from the presets directory
285
    cabbageSet "presetCombo", "populate.directories", presetDirectory
286

287
    x:i, y:i init 0
288
    widgetCount:i init 0
289
    while y < 8 do
290
        while x < 16 do
291
            SWidget = sprintf({{
292
            {
293
            "type": "checkBox",
294
            "bounds":{"left":%d, "top":%d, "width":30, "height":30},
295
            "channels": [{"id": "check%d"}],
296
            "style": {
297
            "on": {"backgroundColor": "#ffa71e"},
298
            "off": {"backgroundColor": "#d5d5d5ff"}
299
            },
300
            "automatable":false
301
            }
302
            }}, 10+x*35, 10+y*35, widgetCount)
303
            cabbageCreate(SWidget)
304
            widgetCount += 1
305
            x += 1
306
        od
307
        x = 0
308
        y += 1
309
    od
310
endin
311

312
/*---------------------------------------*/
313
/* Main sequencer instrument - always on */
314
/*---------------------------------------*/
315
instr SEQUENCER
316
    canShuffle:k init 0
317
    column:k init 0
318
    scrubberPos:k init 0
319
    beatCount:k init 0
320
    bpm:k = cabbageGetValue("bpmSlider")
321
    startStop:CabbageButton init 0, 0
322
    startStop.val, startStop.trig = cabbageGetValue("startStop")
323
    noteDuration:k = cabbageGetValue("durationSlider")
324
    autoShuffle:k = cabbageGetValue("autoShuffle")
325

326
    if(startStop.val == 1) then
327
        if metro:k(bpm/60)==1 then
328
            row:k = 0
329
            while row<numRows do
330
                checkNum:k = column + row*numCols
331
                val:k = cabbageGetValue(sprintfk("check%d", checkNum))
332
                if val == 1 then
333
                    note:k = cabbageGetValue(sprintfk("rowNote%d", row+1))
334
                    event("i", "SYNTH", 0, noteDuration, note, .1)
335
                endif
336
                row = row+1
337
            od
338

339
            if(cabbageGetValue:k("autoShuffle")==1 && (beatCount % (numCols*2) == 0)) then
340
                event("i", "SHUFFLE", 0, .1)
341
            endif
342

343
            beatCount = beatCount + 1
344
            cabbageSet(1, "scrubber", "bounds.left", (column*35+9))
345
            column = (beatCount) % numCols
346

347
        endif
348

349
    endif
350

351
    save:CabbageButton init 0, 0
352
    save.val, save.trig = cabbageGetValue("saveStateBtn")
353
    if save.trig==1 then
354
        event("i", "SAVE_PRESET", 0, .1)
355
    endif
356

357
    loadPreset:S, loadPresetTrig:k = cabbageGetValue("presetCombo")
358
    if loadPresetTrig==1 then
359
        event("i", "LOAD_PRESET", 0, .1)
360
    endif
361

362
    shuffle:CabbageButton init 0, 0
363
    shuffle.val, shuffle.trig = cabbageGetValue("shuffle")
364
    if shuffle.trig==1 then
365
        event("i", "SHUFFLE", 0, .1)
366
    endif
367

368
endin
369

370
/*-----------------*/
371
/* Simple FM Synth */
372
/*-----------------*/
373
instr SYNTH
374

375
    freq:i = cpsmidinn(p4)
376
    p3 = rnd(p3)+0.1
377
    duration:i = p3
378
    aOp2 = oscili(expsegr(0.001, .001, 8, 1*duration, 0.005, 0.3, 0.001), freq*14)
379
    aOp1 = oscili(expsegr(0.001, .001, p5, 10*duration, 0.5, 0.3, 0.001), aOp2+(freq*1.002))
380
    aOp4 = oscili(expsegr(0.001, .001, 7, 15*duration, 0.0001, 0.3, 0.001)*freq, freq*7)
381
    aOp3 = oscili(expsegr(0.001, .001, p5, 15*duration, 0.5, 0.3, 0.001), aOp4+freq)
382
    aOp6 = oscili(expsegr(0.001, .001, 6, 15*duration, 0.0001, 0.3, 0.00001)*freq, freq*1.003)
383
    aOp5 = oscili(expsegr(0.001, .001, p5, 20*duration, 0.5, 0.3, 0.00001), aOp6+(freq*1.003))
384
    fmMix:a = (aOp1+aOp3+aOp5)*.25
385
    filter:a = moogladder(fmMix, rnd(15000), rnd(.8))
386
    pan:i = rnd(1)
387
    outs(filter*pan, filter*(1-pan))
388
    chnmix(filter, "synthOut")
389

390
endin
391

392
/*--------------------------------------------------------*/
393
/* Simple delay effect acting on output signal from Synth */
394
/*--------------------------------------------------------*/
395

396
instr DELAY
397

398
    bpm:k = cabbageGetValue("bpmSlider") / 60
399
    delayTimeSlider:k = cabbageGetValue("delayTime")
400
    delayTime:a = upsamp(delayTimeSlider * (1 / bpm))
401
    delayFeedback:k = cabbageGetValue("delayFeedback")
402
    mute:k = port(changed(bpm)+changed(delayTimeSlider), 0.1)
403
    synthSignal:a = chnget("synthOut")
404

405

406
    delay:a = flanger(synthSignal, delayTime, delayFeedback, 10)
407
    delay *= (1 - mute)
408
    outs(delay, delay)
409

410
    chnclear("synthOut")
411

412
endin
413

414
/* Shuffle the grid pattern and notes randomly */
415
instr SHUFFLE
416

417
    notes:i[] = [36, 38, 40, 42, 43, 45, 47, 48, 50, 52, 53, 55, 57, 59, 60, 62, 64, 65, 67, 69, 71, 72, 74, 76, 77, 79, 81, 83, 84]
418
    numNotes:i = lenarray(notes)
419
    index:i init 0
420
    probability:i = cabbageGetValue("probability")
421

422
    while index < 128 do
423
        randVal:i = rnd(100) > 100-probability ? 1 : 0
424
        checkChannel:S = sprintfk("check%d", index)
425
        cabbageSetValue:i(checkChannel, randVal)
426
        index += 1
427
    od
428

429
    index = 0
430
    while index< numRows do
431
        noteChannel:S = sprintfk("rowNote%d", index+1)
432
        cabbageSetValue(noteChannel, notes[rnd(numNotes)])
433
        index += 1
434
    od
435

436
endin
437

438
/*----------------------------------------------*/
439
/* Save the current state to a JSON preset file */
440
/*----------------------------------------------*/
441
instr SAVE_PRESET
442

443
    fileName:S = cabbageCreateFileName(presetDirectory, ".json")
444
    cabbageSaveState(fileName)
445
    cabbageSet "presetCombo", "populate.directories", presetDirectory
446

447
endin
448

449
/* Load a preset from a selected file in the combo box */
450
instr LOAD_PRESET
451
    items:S[] = cabbageGet("presetCombo", "items")
452
    currentItem:S = cabbageGetValue("presetCombo")
453
    printf_i("Current preset is: %s", 1, currentItem)
454

455
    index:i = 0
456
    while (index < lenarray(items)) do
457
        res:i = strindex(items[index], currentItem)
458
        if(res != -1) then
459
            printf_i("Current preset is: %s at index %d", 1, items[index], index)
460
            cabbageLoadState(items[index])
461
        endif
462
        index += 1
463
    od
464
endin
465

466
</CsInstruments>
467
<CsScore>
468
i"CREATE_GRID" 0 0.1
469
i"SEQUENCER" .1 z
470
i"DELAY" .1 z
471
</CsScore>
472
</CsoundSynthesizer>

Download GridSequencer.csd