Opcodes

cabbageSet

This opcode sets a widget property, i.e,colour.fill, visible, opacity, etc. It can run at init-time or k-time. The k-time variant must use a trigger to initiate the update (see below).

Syntax

cabbageSet:i(SChannel, SProperty, iValue)
cabbageSet:i(SChannel, SProperty, iValue[])
cabbageSet:i(SChannel, SProperty, SValue)
cabbageSet:k(kTrig, SChannel, SProperty, SValue)
cabbageSet:k(kTrig, SChannel, SProperty, kValue)
cabbageSet:k(kTrig, SChannel, SProperty, kValue[])

Initialization

SChannel – the name of the channel to query
SProperty - the property you wish to update. If the property is part of a JSON object, such as "bounds:{"left":0} you can use dot notation, i.e., “bounds.left”
iValue / iValue[] - a value to set the widget property to

Performance

kValue / kValue[] - a value to set the widget property to
SValue - a string value to set the widget property to
kTrig - used to trigger updates at k-rate

The k-rate variant of cabbageSet must use a k-rate trigger to initiate updates. This is to prevent the UI from being saturated with changes. If you need continuous updates, use a metro() opcode, for example: cabbageSet metro(5) …

However, even when sending frequent updates, such as 20 changes per second, the frontend may only process a subset of them. This is because the UI runs at a much slower frame rate than the audio thread.

Example

1
<Cabbage>
2
{
3
    "pluginId"      : "def1",
4
    "enableDevTools": true,
5
    "channelConfig" : [ {"name": "0 in 2 out", "ins": "0", "outs": "2"} ],
6
    "widgets"       : [
7
        { "type": "form", "caption": "GetSet Opcodes", "size": {"height": 500, "width": 580} },
8
        {
9
            "type"   : "rotarySlider",
10
            "channel": "gain",
11
            "bounds" : {"left": 150, "top": 10, "width": 100, "height": 100},
12
            "range"  : {"min": 0, "max": 2, "defaultValue": 1, "skew": 1, "increment": 0.1},
13
            "text"   : "Gain"
14
        },
15
        {
16
            "type"   : "button",
17
            "channel": "button1",
18
            "bounds" : {"left": 0, "top": 10, "width": 100, "height": 30},
19
            "colour" : {
20
                "on" : { "fill": [255, 0, 0] },
21
                "off": { "fill": "#0000ff"   }
22
            },
23
            "text"   : {"on": "I am on", "off": "I am off"}
24
        },
25
        {
26
            "type"      : "textEditor",
27
            "bounds"    : {"left": 17, "top": 169, "width": 341, "height": 40},
28
            "channel"   : "infoText",
29
            "readOnly"  : 1,
30
            "wrap"      : 1,
31
            "scrollbars": 1,
32
            "text"      : "This instrument shows an example..."
33
        },
34
        {
35
            "type"    : "comboBox",
36
            "bounds"  : {"left": 200, "top": 200, "width": 100, "height": 30},
37
            "channels": [ {"id": "combo1", "event": "valueChanged", "range": {}} ],
38
            "items"   : ["One", "Two", "Three"]
39
        }
40
    ]
41
}
42

43
</Cabbage>
44
<CsoundSynthesizer>
45
<CsOptions>
46
-dm0 -n -+rtmidi=NULL -M0 --midi-key=4 --midi-velocity=5
47
</CsOptions>
48
<CsInstruments>
49
; sr set by host
50
ksmps = 64
51
nchnls = 2
52
0dbfs = 1
53

54
/*
55
Test various string variants of cabbageSet opcodes.
56
These opcodes provide an interface to widget properties.
57
*/
58
instr TestStringSetOpcodes
59
    switch:k = metro(10)
60
    if p4 == 0 then
61
        cabbageSet("button1", "text.off", "p4 is 0")
62
    elseif p4 == 1 then
63
        cabbageSet("button1", "text.off", "p4 is 1")
64
    elseif p4 == 2 then
65
        cabbageSet("infoText", "text", "p4 is 2")
66
    elseif p4 == 3 then
67
        cabbageSet("infoText", sprintf({{"text":"%s"}}, "p4 is 3"))
68
    elseif p4 == 4 then
69
        cabbageSet(switch, "infoText", "text", "p4 is 4")
70
    elseif p4 == 5 then
71
        cabbageSet(switch, "infoText", sprintf({{"text":"%s"}}, "p4 is 5"))
72
    elseif p4 == 6 then
73
        cabbageSet("button1", "colour.off.fill", "#00ff00")
74
    endif
75
endin
76

77
/*
78
Test various MYFLT variants of cabbageSet opcodes.
79
These opcodes provide an interface to widget properties.
80
*/
81
instr TestMYFLTSetOpcodes
82
    switch:k = metro(10)
83
    toggle:k = (oscili:k(1, 2) > 0 ? 1 : 0)
84
    if p4 == 0 then
85
        cabbageSet(switch, "gain", "bounds.left", abs(randi:k(400, 10)))
86
    elseif p4 == 1 then
87
        cabbageSet(switch, "gain", "visible", toggle:k)
88
    elseif p4 == 2 then
89
        cabbageSet("gain", "bounds.left", 10)
90
    elseif p4 == 3 then
91
        cabbageSet("gain", sprintf({{"visible":%d}}, 0))
92
    elseif p4 == 4 then
93
        cabbageSet("gain", sprintf({{"visible":%d}}, 1))
94
    endif
95
endin
96

97

98
</CsInstruments>
99
<CsScore>
100
i"TestStringSetOpcodes" 0 1 0
101
i"TestStringSetOpcodes" + 1 1
102
i"TestStringSetOpcodes" + 1 2
103
i"TestStringSetOpcodes" + 1 3
104
i"TestStringSetOpcodes" + 1 4
105
i"TestStringSetOpcodes" + 1 5
106
i"TestStringSetOpcodes" + 1 6
107
f0 z
108
</CsScore>
109
</CsoundSynthesizer>

Download cabbageSet.csd